% +AMDG  This document was begun on 24 November 2008, the
% feast of St. John of the Cross, and it is humbly dedicated
% to him and to the Immacualte Heart of Mary for their
% prayers, and to the Sacred Heart of Jesus for His mercy.


define_pixels(u,fig_height,cap_stem,thin_join,o,stem,stem,bar,tiny,curve);
define_blacker_pixels(thin_join, curve);

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% Prepare the character for the numeral X                 %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

beginchar("X",9u#,fig_height#,0); "The Numeral X";
italcorr fig_height#*slant-.5u#;

z1l = (u, 2(h/3));
z2 = ((w/3), h);
z3 = (2(w/3), (8h/9)+o);
z4r = (w-u, h+o);
z5 = (2u, h/4);
y6 = y1;
x6 = x3;
z7l = (w/2, 0);
z8 = (w-u,2h/5);
x9 = x8;
y9 = .4(y7 + y8);
z10 = .5[z7,z8];
z11 = .5[z7,z6];

penpos1(1.3thin_join,0);
penpos2(.7curve,270);
penpos3(1.3thin_join,270);
penpos4(1.3thin_join,0);
penpos5(curve,0);
penpos6(1.3thin_join,315);
penpos7(1.3thin_join,90);
penpos8(1.3thin_join,225);
penpos9(1.3thin_join,125);
penpos10(1.3thin_join,30);
penpos11(1.3thin_join,25);

penstroke z1e{up}..{right}z2e{right}..z3e..z4e;
penstroke z4e..z6e..z5e..z7e..z9e..z8e..z11e..z10e;

%penstroke z1e{up}..{left}z2e{left}..z3e..z4e;
%penstroke z4e..z6e..z5e..z7e..z9e..z8e..z11e..z10e;

penlabels(1,2,3,4,5,6,7,8,9,10,11);

endchar;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% Prepare the character for the numeral E                 %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

beginchar("E",9u#,fig_height#,0); "The Numeral E";
italcorr fig_height#*slant-.5u#;

z1 = (w-u, 3h/4);
z2 = (w-u, h/4);
z3 = (2w/3, h/2);
z4 = (u, 3h/4);
z5 = (u, h/4);
z6l = (w/2,h);
z7l = (w/2,0);
z8 = (w-u, 7h/8);
z9 = z3;
z10 = (w-u, h/8);
z11 = 1/3[z8,z4];
z12 = 1/3[z10,z5];

penpos1(1.3thin_join,0);
penpos8(1.3thin_join,45);
penpos6(1.3thin_join,90);
penpos4(curve,180);
penpos3(1.3thin_join,270);
penpos5(curve,180);
penpos7(1.3thin_join,270);
penpos2(1.3thin_join,0);
penpos9(1.3thin_join,90);
penpos10(1.3thin_join,315);
penpos11(1.3thin_join,-180);
penpos12(1.3thin_join,180);

penstroke z11e..z1e..z8e..z6e..z4e..{right}z3e;
penstroke z12e..z2e..z10e..z7e..z5e..{right}z9e;

penlabels(1,2,3,4,5,6,7,8,9,10,11,12);

endchar;
end;